test:
    cargo test

release crate="musixmatch-inofficial":
    #!/usr/bin/env bash
    set -e

    CRATE="{{crate}}"
    INCLUDES='--include-path README.md --include-path LICENSE --include-path Cargo.toml'
    CHANGELOG="CHANGELOG.md"

    if [ "$CRATE" = "musixmatch-inofficial" ]; then
        INCLUDES="$INCLUDES --include-path src/** --include-path tests/** --include-path testfiles/**"
    else
        if [ ! -d "$CRATE" ]; then
            echo "$CRATE does not exist."; exit 1
        fi
        INCLUDES="$INCLUDES --include-path $CRATE/**"
        CHANGELOG="$CRATE/$CHANGELOG"
        CRATE="musixmatch-$CRATE" # Add crate name prefix
    fi

    VERSION=$(cargo pkgid --package "$CRATE" | tr '#@' '\n' | tail -n 1)
    TAG="${CRATE}/v${VERSION}"
    echo "Releasing $TAG:"

    if git rev-parse "$TAG" >/dev/null 2>&1; then echo "version tag $TAG already exists"; exit 1; fi

    CLIFF_ARGS="--tag v${VERSION} --tag-pattern ${CRATE}/* --unreleased $INCLUDES"
    echo "git-cliff $CLIFF_ARGS"
    if [ -f "$CHANGELOG" ]; then
        git-cliff $CLIFF_ARGS --prepend "$CHANGELOG"
    else
        git-cliff $CLIFF_ARGS --output "$CHANGELOG"
    fi

    editor "$CHANGELOG"

    git add "$CHANGELOG"
    git commit -m "chore(release): release $CRATE v$VERSION"

    awk 'BEGIN{RS="(^|\n)## [^\n]+\n*"} NR==2 { print }' "$CHANGELOG" | git tag -as -F - --cleanup whitespace "$TAG"

    echo "🚀 Run 'git push origin $TAG' to publish"